vendor: OpenCV 5.0.0 snapshot at 40738fb16ceddb5fb3fea747585f7ce6abb0605b

2026-08-22 00:10:33 +08:00
commit f7f077da11
6933 changed files with 2335208 additions and 0 deletions
@@ -0,0 +1,14 @@
+# --- FB ---
+set(HAVE_FRAMEBUFFER ON)
+if(WITH_FRAMEBUFFER_XVFB)
+  try_compile(HAVE_FRAMEBUFFER_XVFB
+    "${CMAKE_CURRENT_BINARY_DIR}"
+    "${OpenCV_SOURCE_DIR}/cmake/checks/framebuffer.cpp")
+  if(HAVE_FRAMEBUFFER_XVFB)
+    message(STATUS "Check virtual framebuffer - done")
+  else()
+    message(STATUS
+      "Check virtual framebuffer - failed\n"
+      "Please install the xorg-x11-proto-devel or x11proto-dev package\n")
+  endif()
+endif()
@@ -0,0 +1,49 @@
+# --- GTK ---
+ocv_clear_vars(HAVE_GTK HAVE_GTK2 HAVE_GTK3 HAVE_GTKGLEXT)
+if(WITH_GTK)
+  if(NOT WITH_GTK_2_X)
+    ocv_check_modules(GTK3 gtk+-3.0)
+    if(HAVE_GTK3)
+      ocv_add_external_target(gtk3 "${GTK3_INCLUDE_DIRS}" "${GTK3_LIBRARIES}" "HAVE_GTK3;HAVE_GTK")
+      set(HAVE_GTK TRUE)
+    endif()
+  endif()
+  if((PROJECT_NAME STREQUAL "OpenCV" AND HIGHGUI_ENABLE_PLUGINS) OR NOT HAVE_GTK3)
+    ocv_check_modules(GTK2 gtk+-2.0)
+    if(HAVE_GTK2)
+      set(MIN_VER_GTK "2.18.0")
+      if(GTK2_VERSION VERSION_LESS MIN_VER_GTK)
+        message(FATAL_ERROR "GTK support requires a minimum version of ${MIN_VER_GTK} (${GTK2_VERSION} found)")
+      else()
+        ocv_add_external_target(gtk2 "${GTK2_INCLUDE_DIRS}" "${GTK2_LIBRARIES}" "HAVE_GTK2;HAVE_GTK")
+        set(HAVE_GTK TRUE)
+      endif()
+    endif()
+  endif()
+  if((WITH_OPENGL OR HAVE_OPENGL) AND (HAVE_GTK2 OR HAVE_GTK3))
+    if(HAVE_GTK2)
+      ocv_check_modules(GTKGLEXT gtkglext-1.0)
+      if(HAVE_GTKGLEXT)
+        # HACK for https://github.com/opencv/opencv/issues/20850
+        # pkg-config reports some include directories that do not exist. Just filter them out.
+        set(GTKGLEXT_INCLUDE_DIRS_EXISTS "")
+        foreach(p ${GTKGLEXT_INCLUDE_DIRS})
+          if (EXISTS "${p}")
+            list(APPEND GTKGLEXT_INCLUDE_DIRS_EXISTS "${p}")
+          endif()
+        endforeach()
+        ocv_add_external_target(gtkglext "${GTKGLEXT_INCLUDE_DIRS}" "${GTKGLEXT_LIBRARIES}" "HAVE_GTKGLEXT")
+      endif()
+    endif()
+  endif()
+elseif(HAVE_GTK)
+  ocv_add_external_target(gtk "${GTK_INCLUDE_DIRS}" "${GTK_LIBRARIES}" "${GTK_DEFINES};HAVE_GTK")
+endif()
+
+if(WITH_OPENGL)
+  find_package(OpenGL QUIET)
+  if(OPENGL_FOUND)
+    set(HAVE_OPENGL TRUE)
+    ocv_add_external_target(gtk_opengl "${OPENGL_INCLUDE_DIRS}" "${OPENGL_LIBRARIES}" "HAVE_OPENGL")
+  endif()
+endif()
@@ -0,0 +1,41 @@
+# --- Wayland ---
+macro(ocv_wayland_generate protocol_file output_file)
+    add_custom_command(OUTPUT ${output_file}.h
+            COMMAND ${WAYLAND_SCANNER_EXECUTABLE} client-header < ${protocol_file} > ${output_file}.h
+            DEPENDS ${protocol_file})
+    add_custom_command(OUTPUT ${output_file}.c
+            COMMAND ${WAYLAND_SCANNER_EXECUTABLE} private-code < ${protocol_file} > ${output_file}.c
+            DEPENDS ${protocol_file})
+    list(APPEND WAYLAND_PROTOCOL_SOURCES ${output_file}.h ${output_file}.c)
+endmacro()
+
+ocv_clear_vars(HAVE_WAYLAND_CLIENT HAVE_WAYLAND_CURSOR HAVE_XKBCOMMON HAVE_WAYLAND_PROTOCOLS HAVE_WAYLAND_EGL)
+if(WITH_WAYLAND)
+    ocv_check_modules(WAYLAND_CLIENT wayland-client)
+    if(WAYLAND_CLIENT_FOUND)
+        set(HAVE_WAYLAND_CLIENT ON)
+    endif()
+    ocv_check_modules(WAYLAND_CURSOR wayland-cursor)
+    if(WAYLAND_CURSOR_FOUND)
+        set(HAVE_WAYLAND_CURSOR ON)
+    endif()
+    ocv_check_modules(XKBCOMMON xkbcommon)
+    if(XKBCOMMON_FOUND)
+        set(HAVE_XKBCOMMON ON)
+    endif()
+    ocv_check_modules(WAYLAND_PROTOCOLS wayland-protocols>=1.13)
+    if(HAVE_WAYLAND_PROTOCOLS)
+        pkg_get_variable(WAYLAND_PROTOCOLS_BASE wayland-protocols pkgdatadir)
+        find_host_program(WAYLAND_SCANNER_EXECUTABLE NAMES wayland-scanner REQUIRED)
+    endif()
+
+    if(HAVE_WAYLAND_CLIENT AND HAVE_WAYLAND_CURSOR AND HAVE_XKBCOMMON AND HAVE_WAYLAND_PROTOCOLS)
+        set(HAVE_WAYLAND TRUE)
+    endif()
+
+    # WAYLAND_EGL is option
+    ocv_check_modules(WAYLAND_EGL wayland-egl)
+    if(WAYLAND_EGL_FOUND)
+        set(HAVE_WAYLAND_EGL ON)
+    endif()
+endif()
@@ -0,0 +1,15 @@
+#--- Win32 UI ---
+ocv_clear_vars(HAVE_WIN32UI)
+if(WITH_WIN32UI)
+  try_compile(HAVE_WIN32UI
+    "${CMAKE_CURRENT_BINARY_DIR}"
+    "${OpenCV_SOURCE_DIR}/cmake/checks/win32uitest.cpp"
+    CMAKE_FLAGS "-DLINK_LIBRARIES:STRING=user32;gdi32")
+  if(HAVE_WIN32UI)
+    set(__libs "user32" "gdi32")
+    if(OpenCV_ARCH STREQUAL "ARM64")
+      list(APPEND __libs "comdlg32" "advapi32")
+    endif()
+    ocv_add_external_target(win32ui "" "${__libs}" "HAVE_WIN32UI")
+  endif()
+endif()
@@ -0,0 +1,48 @@
+if(PROJECT_NAME STREQUAL "OpenCV")
+  set(ENABLE_PLUGINS_DEFAULT ON)
+  if(EMSCRIPTEN OR IOS)
+    set(ENABLE_PLUGINS_DEFAULT OFF)
+  endif()
+  set(HIGHGUI_PLUGIN_LIST "" CACHE STRING "List of GUI backends to be compiled as plugins (gtk, gtk2/gtk3, qt, win32 or special value 'all')")
+  set(HIGHGUI_ENABLE_PLUGINS "${ENABLE_PLUGINS_DEFAULT}" CACHE BOOL "Allow building and using of GUI plugins")
+  mark_as_advanced(HIGHGUI_PLUGIN_LIST HIGHGUI_ENABLE_PLUGINS)
+
+  string(REPLACE "," ";" HIGHGUI_PLUGIN_LIST "${HIGHGUI_PLUGIN_LIST}")  # support comma-separated list (,) too
+  string(TOLOWER "${HIGHGUI_PLUGIN_LIST}" HIGHGUI_PLUGIN_LIST)
+  if(NOT HIGHGUI_ENABLE_PLUGINS)
+    if(HIGHGUI_PLUGIN_LIST)
+      message(WARNING "HighGUI: plugins are disabled through HIGHGUI_ENABLE_PLUGINS, so HIGHGUI_PLUGIN_LIST='${HIGHGUI_PLUGIN_LIST}' is ignored")
+      set(HIGHGUI_PLUGIN_LIST "")
+    endif()
+  else()
+    # Make virtual plugins target
+    if(NOT TARGET opencv_highgui_plugins)
+      add_custom_target(opencv_highgui_plugins ALL)
+    endif()
+  endif()
+endif()
+
+#
+# Detect available dependencies
+#
+
+if(NOT PROJECT_NAME STREQUAL "OpenCV")
+  include(FindPkgConfig)
+endif()
+
+macro(add_backend backend_id cond_var)
+  if(${cond_var})
+    include("${CMAKE_CURRENT_LIST_DIR}/detect_${backend_id}.cmake")
+  endif()
+endmacro()
+
+add_backend("gtk" WITH_GTK)
+add_backend("win32ui" WITH_WIN32UI)
+add_backend("wayland" WITH_WAYLAND)
+add_backend("framebuffer" WITH_FRAMEBUFFER)
+
+# TODO cocoa
+# TODO qt
+# TODO opengl
+
+# FIXIT: move content of cmake/OpenCVFindLibsGUI.cmake here (need to resolve CMake scope issues)
@@ -0,0 +1,61 @@
+function(ocv_create_builtin_highgui_plugin name target)
+
+  ocv_debug_message("ocv_create_builtin_highgui_plugin(${ARGV})")
+
+  if(NOT TARGET ${target})
+    message(FATAL_ERROR "${target} does not exist!")
+  endif()
+  if(NOT OpenCV_SOURCE_DIR)
+    message(FATAL_ERROR "OpenCV_SOURCE_DIR must be set to build the plugin!")
+  endif()
+
+  message(STATUS "HighGUI: add builtin plugin '${name}'")
+
+  foreach(src ${ARGN})
+    list(APPEND sources "${CMAKE_CURRENT_LIST_DIR}/src/${src}")
+  endforeach()
+
+  add_library(${name} MODULE ${sources})
+  target_include_directories(${name} PRIVATE "${CMAKE_CURRENT_BINARY_DIR}")
+  target_compile_definitions(${name} PRIVATE BUILD_PLUGIN)
+  target_link_libraries(${name} PRIVATE ${target})
+
+  foreach(mod opencv_highgui
+      opencv_core
+      opencv_imgproc
+      opencv_imgcodecs
+      opencv_videoio  # TODO remove this dependency
+  )
+    ocv_target_link_libraries(${name} LINK_PRIVATE ${mod})
+    ocv_target_include_directories(${name} "${OPENCV_MODULE_${mod}_LOCATION}/include")
+  endforeach()
+
+  if(WIN32)
+    set(OPENCV_PLUGIN_VERSION "${OPENCV_DLLVERSION}" CACHE STRING "")
+    if(CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
+      set(OPENCV_PLUGIN_ARCH "_64" CACHE STRING "")
+    else()
+      set(OPENCV_PLUGIN_ARCH "" CACHE STRING "")
+    endif()
+  else()
+    set(OPENCV_PLUGIN_VERSION "" CACHE STRING "")
+    set(OPENCV_PLUGIN_ARCH "" CACHE STRING "")
+  endif()
+
+  set_target_properties(${name} PROPERTIES
+    CXX_STANDARD 11
+    CXX_VISIBILITY_PRESET hidden
+    DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
+    OUTPUT_NAME "${name}${OPENCV_PLUGIN_VERSION}${OPENCV_PLUGIN_ARCH}"
+  )
+
+  if(WIN32)
+    set_target_properties(${name} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${EXECUTABLE_OUTPUT_PATH})
+    install(TARGETS ${name} OPTIONAL LIBRARY DESTINATION ${OPENCV_BIN_INSTALL_PATH} COMPONENT plugins)
+  else()
+    install(TARGETS ${name} OPTIONAL LIBRARY DESTINATION ${OPENCV_LIB_INSTALL_PATH} COMPONENT plugins)
+  endif()
+
+  add_dependencies(opencv_highgui_plugins ${name})
+
+endfunction()